perm filename LOWCOR[KA,SYS]1 blob
sn#224436 filedate 1976-07-10 generic text, type C, neo UTF8
COMMENT ⊗ VALID 00006 PAGES
C REC PAGE DESCRIPTION
C00001 00001
C00002 00002 LOWCOR 6 SEPT 67
C00006 00003 BEGIN PWAIT
C00011 00004 DEVOPR: SIXBIT /CTY/ OPERATORS CONSOLE DEVICE = CTY.
C00014 00005 MONTH TABLE FOR DAYTIME PRINTING
C00015 00006 HISTOGRAM STATISTIC GATHERING ROUTINE.
C00018 ENDMK
C⊗;
SUBTTL LOWCOR 6 SEPT 67
SHDACS: BLOCK 20 ;ACS STORED HERE DURING ZSHAD
; BEGINNING OF PROTECTED PART OF MONITOR . . .
CHKBEG←←.
HIBEG←←0
IFN FTHSYS,<
HISYS
HIBEG←←. ;FOR USER-MODE STARTUP (SEE ONCE)
LOSYS
>;FTHSYS
;; ON THIS PAGE LIE SOME VERY COMMON AND USEFUL ROUTINES . . .
TPOPJ1: AOS -1(P) ;RESTORE TAC THEN SKIP RETURN
TPOPJ: POP P,TAC ;RESTORE TAC
POPJ P, ;AND RETURN
CPOPJ2: AOS (P) ;DOUBLE SKIP SUBROUTINE RETURN
CPOPJ1: AOSA (P) ;SKIP SUBROUTINE RETURN
PIONJ: CONO PI,PION
CPOPJ: POPJ P,
IFN PRCONF-1,< ;EITHER VERSION THAT INCLUDES KA10
FMCHK: SKPNKA ;SKIP IF NOT THE KA10
PUSHJ P,ZSHAD2
JRST CPOPJ1 ;FM ENB OK
MOVE TAC,[440700,,[ASCIZ/TURN ON FM ENB. THEN CONTINUE.
/]]
JSR DDTTYP
POP P,DDTTYP
JRST 4,@DDTTYP
>;PRCONF≠1
IFE PRCONF-1,< FMCHK: JRST CPOPJ1 >
ZSHAD2: PUSH P,[JFCL]
JRST ZSHAD3
ZSHAD: SKPKA ;IS THIS THE KA10?
POPJ P, ;NO. DO NOTHING.
PUSH P,[CONO PAG,7]
ZSHAD3: CONSO APR,MAOFF ;IS KA IN MAOFF MODE?
JRST ZSHD3A ;NO.
PUSH P,140 ;SAVE THE UUO LOCATIONS
PUSH P,141
JRST ZSHD3B
ZSHD3A: PUSH P,40
PUSH P,41
ZSHD3B:
IFE FTPAGER,< PUSH P,LASTPR > ;NOT FTPAGER
IFN FTPAGER,< CONO PAG,4 ;TURN OFF MAPPING >;FTPAGER
MOVEM 17,SHDACS+17 ;SAVE THE REAL AC'S SO WE DON'T ZERO THEM
MOVEI 17,SHDACS
BLT 17,SHDACS+16
MOVE 0,[JRST ZSHAD1]
CONSZ APR,MAOFF
MOVEM 0,141 ;SET TO TRAP OUR ILLEGAL INSTRUCTION
CONSO APR,MAOFF
MOVEM 0,41 ;SET TO TRAP OUR ILLEGAL INSTRUCTION
MOVE 17,[776000,,2000]
IFE FTPAGER,< MOVEM 17,LASTPR >;NOT FTPAGER
DATAO APR,17
MOVSI 17,USRSHD
BLT 17,17
JRST 1,1 ;RUN USER MODE CODE IN ACS
ZSHAD1: EXCH SHDACS ;SHDACS←0 IF NO FM ENB
MOVE 17,[SHDACS+1,,1]
BLT 17,17
IFE FTPAGER,< POP P,LASTPR >;NOT FTPAGER
CONSO APR,MAOFF
JRST ZSHD1A
POP P,141
POP P,140
JRST ZSHD1B
ZSHD1A: POP P,40
POP P,40
ZSHD1B:
IFE FTPAGER,< DATAO APR,LASTPR >;NOT FTPAGER
IFN FTPAGER,< DATAO APR,[776000,,0]
XCT (P) >;FTPAGER
POP P,(P)
SKIPN SHDACS
AOS (P) ;SKIP RETURN IF FM ENB OFF
POPJ P,
USRSHD: -1 ;GETS LOADED INTO ACS (STARTING AT ZERO)
SETZM -2000 ;CLEAR SHADOW ZERO
BLT 17,-2000+17 ;BLT ACS INTO SHADOW MEM
JRST 4, ;GET BACK TO EXEC MODE
BLOCK USRSHD-.+17
0,,-2000 ;17
BEGIN PWAIT
;XXXCSC: 0 ;-1 IF P1 WANTS IT OR HAS IT.
; 0 ;-1 IF P2 WANTS IT OR HAS IT.
; 0 ;0 IF P1 HAD IT LAST, -1 IF P2 HAD IT LAST
; 0 ;IF GREATER THAN ZERO, THE NUMBER OF TIMES
;SOME PROCESSOR HAS THE SYNCRONIZER.
↑PWAIT: PUSH P,TAC ;SAVE AN AC
XCT @-1(P) ;TAC←CONTROL CELL ADDRESS
PUSH P,TAC1
CONI PI,TAC1
ANDI TAC1,PION
JUMPN PID,P2WAIT ;JUMP IF P2.
SKIPP1 ;MAKE SURE PID IS RIGHT.
JRST PWAITE
SKIPE 3(TAC) ;IS THE SYNCHRONIZER ALREADY GRANTED?
SKIPN (TAC) ;YES. GRANTED TO P1?
JRST P1L0 ;NEED TO SYNCHRONIZE
P1XIT: AOS 3(TAC) ;COUNT US AGAIN AS A SYNCHRONIZER USER
CONO PI,(TAC1) ;RESTORE STATE OF PI IN CASE WE TURNED IT OFF.
SETZM 2(TAC) ;AND SET TOGGLE TO P1
POP P,TAC1
JRST TPOPJ1 ;RESTORE TAC AND RETURN.
P1L0: SKIPE 1(TAC) ;WAIT FOR P2 TO NOT BE REQUESTING
JRST P1L0
CONO PI,PIOFF ;KEEP OUT INTERRUPTS
SETOM (TAC) ;SET OUR REQUEST.
SKIPN 1(TAC) ;IS P2 REQUESTING?
JRST P1XIT ;NO. WE HAVE IT!
CONO PI,(TAC1) ;REENABLE INTS.
SKIPN 2(TAC) ;P2 REQUESTING. DID WE HAVE SYNC. LAST?
SETZM (TAC) ;YES. DROP REQUEST AND LET P2 HAVE IT.
JRST P1L0 ;WAIT FOR P2 TO DROP ITS REQUEST
P2WAIT: SKIPP2 ;MAKE SURE THIS IS TRULY THE RIGHT PROCESSOR
JRST PWAITE
SKIPE 3(TAC) ;DOES SOMEONE ALREADY HAVE IT?
SKIPN 1(TAC) ;YES. IS IT US?
JRST P2L0 ;NO ONE HAS IT, OR P1 HAS IT. WAIT FOR IT.
P2XIT: AOS 3(TAC)
CONO PI,(TAC1)
SETOM 2(TAC) ;MARK THAT P2 HAD IT LAST
POP P,TAC1
JRST TPOPJ1
P2L0: SKIPE (TAC) ;WAIT FOR P1 TO DROP REQUEST
JRST .-1
CONO PI,PIOFF
SETOM 1(TAC) ;SET OUR REQUEST
SKIPN (TAC) ;IS P1 REQUESTING?
JRST P2XIT ;NO. WE GOT IT!
CONO PI,(TAC1)
SKIPE 2(TAC) ;DID WE HAVE IT LAST TIME?
SETZM 1(TAC) ;YES. WE DROP OUR REQUEST
JRST P2L0 ;AND LOOP, WAITING FOR P1 TO DROP HIS.
PWAITE: PUSHACS
PUSHJ P,DISMES
ASCIZ /PID CLOBBERED AT PWAIT. PID = /
MOVE TAC,PID-17(P)
PUSHJ P,DISOCT
PUSHJ P,DISMES
ASCIZ /; PC = /
MOVE TAC,-21(P)
PUSHJ P,DISLOC
PUSHJ P,DISCRLF
SKIPP2
JRST PWE1
PUSHJ P,DISMES
ASCIZ /PUSH CONTINUE
/
JRST 4,PWE2 ;DISFLU ISN'T NEEDED ON P2
PWE1: PUSHJ P,DISFLU
PUSHJ P,WDDTCAL
PWE2: POPACS
MOVEI PID,0
SKIPP1
MOVEI PID,P2PID
POP P,TAC1
POP P,TAC
JRST PWAIT
↑XWAIT: PUSH P,TAC
XCT @-1(P)
SKIPG 3(TAC) ;SKIP IF WINNING
JRST XWLOSE ;OVER XSYNCED.
JUMPN PID,XW2 ;
SOSG 3(TAC) ;DECREMENT THE COUNT OF NUMBER OF TIMES SYNCED
SETZM (TAC) ;DROP P1'S REQUEST.
JRST TPOPJ1
XW2: SOSG 3(TAC)
SETZM 1(TAC) ;DROP P2'S REQUEST
JRST TPOPJ1
XWLOSE: PUSHACS
PUSHJ P,DISMES
ASCIZ /OVER XSYNC'ED. PC = /
HRRZ TAC,-21(P) ;-1 FOR PUSH P,TAC
PUSHJ P,DISLOC
PUSHJ P,DISMES
ASCIZ /
CHECK PID OR
PDP-10: TYPE POPJ 3,$X
PDP-6: CONTINUE
/
PUSHJ P,DISFLU
SKIPP1
JRST 4,.+2
PUSHJ P,DDTCAL
POPACS
SKIPN PID
SETZM (TAC)
SKIPE PID
SETZM 1(TAC)
SETZM 3(TAC)
JRST TPOPJ1
BEND PWAIT
DEVOPR: SIXBIT /CTY/ ;OPERATORS CONSOLE DEVICE = CTY.
;PUBLIC LOGICAL NAME "OPR" WILL BE THIS DEVICE
;ALSO UNEXPLAINED MONITOR ERROR MESSAGE WILL BE TYPED
;ON TTY OPR(FIRST TTY TYPED ON IF DEVOPR=0)
;FIGMAY AND FIGMAX ARE DEFINED IN HEAD
RADIX =10
CONFIG: FIGMAY (\FIGMAX(Stanford,\SERIES))
RADIX 8
SYSTAP: SIXBIT /DSK/
;BYTE POINTERS
PUUOAC: POINT 4,UUO,12 ;UUO AC FIELD
PIOMOD: POINT 4,IOS,35 ;MODE BITS
PJOBN: POINT 6,DEVCHR(DDB),5 ;DEVICE JOB ASSIGNMENT
PDVBLN: POINT PUNITP,DEVCHR(DDB),35 ; DEVICE BUFFER LENGTH
PUNIT: POINT PUNITS,DEVCHR(DDB),35-PUNITP ;DEVICE UNIT NO.
PSEGN: POINT 6,JBTSTS(J),35 ; NUMBER OF HIGH SEGMENT THIS JOB HAS
PDSEGN: POINT 6,(AC1),35 ; NUMBER OF SEGMENT IN JBTDTS
PSINF0: POINT 6,JBTSIN,35 ; HEAD OF LIST, FORWARD LINK
PSINFJ: POINT 6,JBTSIN(J),35 ; FORWARD LINK (J)
PSINFT: POINT 6,JBTSIN(TAC),35 ; FORWARD LINK (TAC)
PSINB0: POINT 6,JBTSIN,29 ; HEAD OF LIST, BACKWARD LINK
PSINBJ: POINT 6,JBTSIN(J),29 ; BACKWARD LINK (J)
PSINBT: POINT 6,JBTSIN(TAC),29 ; BACKWARD LINK (TAC)
PMONTB: POINT 6,MONTAB(TAC),5 ;POINTER TO NO. DAYS IN MONTH
REPEAT 0,<
PRUNB: POINT 2,JB2STS(J),16 ; POINTER TO PROCESSOR RUN BITS
>
PDVTIM: POINT 6,DEVCHR(DDB),17 ;TIME IN SECONDS BEFORE DEVICE
;IS SAID TO BE HUNG
PDVCNT: POINT 6,DEVCHR(DDB),11 ;COUNTER DOWN EACH SECOND,
;1 TO 0 TRANSITION MEANS HUNG DEVICE
IMGIN: POINT 9,JBTSWP(J),35 ;POINTER TO INCORE IMAGE (PAGES)
IMGOUT: POINT 9,JBTSWP(J),26 ;POINTER TO OUTCORE IMAGE
IMGINT: POINT 9,JBTSWP(DDB),35 ;POINTER TO INCORE IMAGE
FBNXTP: POINT 6,JBTSWP(J),17 ;NEXT LOG TRACK TO ASSIGN FOR SWAPOUT
↓SYSPPN: SIXBIT / 1 1/ ;1,1 IS SYSPPN ;JS
↓DUMPPN: SIXBIT / 1 2/ ;1,2 IS DUMPPP ;JS
↓CUSPPN: SIXBIT / 1 3/ ;1,3 IS CUSP AREA
HELPPP: SIXBIT /100100/ ;100,100 IS HELPPP AND DEMOS ;JS
;MONTH TABLE FOR DAYTIME PRINTING
MONTAB: =30B5+"Jan"
=27B5+"Feb"
=30B5+"Mar"
=29B5+"Apr"
=30B5+"May"
=29B5+"Jun"
=30B5+"Jul"
=30B5+"Aug"
=29B5+"Sep"
=30B5+"Oct"
=29B5+"Nov"
=30B5+"Dec"
MIDNIT: =60*=60*=24*JIFSEC ;NO OF JIFFIES TILL MIDNIGHT
; THE FOLLOWING IS A LIST OF THE ASCII NAMES OF THE QUEUES
; SO SYSTAT CAN READ THEM
QNAMS:
DEFINE X!(A) {<ASCII /A!Q />}
QUEUES
CODES
PQUEUES
ASCII /CMQ / ; DON'T FORGET COMMAND WAIT!!
; HISTOGRAM STATISTIC GATHERING ROUTINE.
;
; CALL: PUSHJ P,HG
; RETURN HERE ALWAYS
;
; CURRENTLY, THIS ROUTINE IS CALLED (ONLY) BY KDBINT.
; THUS, STATISTICS ARE GATHERED ON EVERY KEYSTROKE OF EVERY
;MICROSWITCH KEYBOARD.
; THIS ROUTINE, ONCE EVERY HGSET TIMES IT IS CALLED, WILL
;INCREMENT ONE & ONLY ONE OF THE 5 COUNTERS: HGCH6,HGUSR,HGSPW,HGUUO,
;HGSYS. IN ADDITION, IF HGSYS IS INCREMENTED, THEN ONE OF THE
;COUNTERS HGCNTS WILL BE INCREMENTED, AND IF HGUSR IS INCREMENTED
;AT A TIME WHEN THE NULL JOB IS RUNNING, THEN EITHER HGNULL OR HGIDLE
;DEPENDING ON THE STATE OF <TQ+RUNQ>.
;
; THIS ROUTINE CLOBBERS ACCUMULATOR TAC, RETURNS WITH POPJ, P.
;NO OTHER ACCUMULATORS ARE USED.
IFN FTHG,<
HG:
SOSE HGYET ;TIME TO DO OUR THING YET?
POPJ P, ;NO.
MOVE TAC,HGSET
MOVEM TAC,HGYET ;RESET TIMER
CONSZ PI,40 ;CH2 ACTIVE?
AOS HGCH2 ;YES. COUNT IT
CONSZ PI,1000 ;CHANNEL 6 IN PROGRESS?
AOSA HGCH6 ;YES, INCREMENT OUR COUNTER AND RETURN
SKIPA TAC,CH5 ;ELSE, GET PC WORD
POPJ P, ;RETURN FOR CH6 ACTIVE.
SKIPE SPWUUF
JRST ISHGSP ;CATCH SPCWAR UUO'S ALSO
TLNN TAC,USRMOD ;WE INTERRUPTED A USER?
JRST HG4 ;NO. WE'RE IN THE SYSTEM
CONSZ PI,400 ;USER IN CHANNEL 7?
ISHGSP: AOSA HGSPW ;YES - SPACEWAR USER
AOSA HGUSR ;NO. PLAIN USER CODE.
POPJ P,
SKIPE JOB ;NULL JOB RUNNING?
POPJ P, ;NO
SKIPGE JBTQ-RUNQ ;IS THIS IDLE OR WASTED
SKIPL JBTQ-TQ
AOSA HGNULL ;WASTED TIME (RUNQ OR TQ NOT EMPTY)
AOS HGIDLE ;IDLE TIME.
POPJ P,
HG4: CONSO PI,400 ;CHANNEL 7 IN PROGRESS?
AOSA HGUUO ;NO WE'RE IN A UUO.
AOSA HGSYS ;WE INTERRUPTED CHANNEL 7.
POPJ P,
HRRZ TAC,HGCODE ;GET IDENTIFICATION CODE
CAIL TAC,HGNMAX ;A LEGAL CODE?
MOVEI TAC,0 ;NO, MAKE IT THE DEFAULT CODE
AOS HGCNTS(TAC) ;INCREMENT APPROPRIATE HISTOGRAM COUNTER
POPJ P,
>